Autorisation : Membre
Nb de messages : 8
Inscrit le : Sam 22 Déc 2012, 12:32
Posté le : Sam 22 Déc 2012, 20:07
Bonjour, tout d'abord puisque je suis nouveau sur ce forum, je tient à me présenter brièvement.
Je m'appel maxence comme vous avez pu le constater, et je vais sur mes 17 ans. Je suis actuellement en 1ère S SI. Je fait du tennis, et biensûr je programme sur ma TI 84+ (je sais que c'est censé être pour les 82 mais bon), et je suis déjà inscrit sur le forum espace-ti.
TXT est donc un programme que j'ai créer pour le ti-concours, c'est un programme de traitement de texte.
et le code: (le "lTXT" désigne la liste TXT, =/= pour n'inégalité, @ pour la variable [theta] et "->" pour sto-> )
Code
:SetUpEditor TXT
:0->lTXT(1
:If 1=dim(lTXT:Goto ST
:Lbl MN:ClrHome
:Menu(" (TXT... ) ","(NOUVEAU)",NV,"(OUVRIR)",OV,"(RECEVOIR)",RV,"(QUITTER)",QT
:Lbl QT
:If 2=dim(lTXT:DelVar Str9DelVar lTXT
:DelVar Str0DelVar Str1Output(1,1,"
:Return
:Lbl RV
:Pause "(ENTER:RECEVOIR)
:Output(1,2,"RECEPTION...
:DelVar Str0:0
:Repeat Ans=3 or length(Str0
: GetCalc(Str0
: Ans+1
:End
:ClrHome
:If 3=Ans:Menu("ECHEC RECEPTION ","(REESSAYER)",RV,"(RETOUR)",MN
:Str9+Str0->Str9
:augment(lTXT,{length(Str0->TXT
:Pause "(REUSSIE... )
:Goto MN
:Lbl NV
:Disp "(TITRE... )
:Input ":",Str0
:If Str0="ANNUL
:Goto MN
:Str9+sub(Str0+" ",1,14->Str9
: augment(lTXT,{0->TXT
:dim(Ans->A
:Repeat 1
: Lbl EC
: ClrHome
: Input "("+sub(Str9,1+sum(lTXT,2,A-1),14)+")",Str0
: sub(Str0+" ",1,16iPart(1+(length(Str0)-1)/16->Str0
: If A=dim(lTXT:Then
: sub(Str9,1,14+sum(lTXT,2,A-1))+Ans->Str9
: Else
: sum(lTXT,2,A
: sub(Str9,1,14+Ans-lTXT(A))+Str0+sub(Str9,1+Ans,length(Str9)-Ans->Str9
: End
: 14+length(Str0->lTXT(A
:End
:Goto MN
:Lbl OV
:If 2=dim(lTXT:Menu("PAS DE TEXTE ","(RETOUR)",MN
:3->A
:Lbl LT
:Repeat @=105
: getKey->@
: If @=21:Goto MN
: If @=23:Goto S1
: If @=45:Goto ST
: min(dim(lTXT),max(3,A+(@=26)-(@=24->A
: Output(1,1,"("+sub(Str9,1+sum(lTXT,2,A-1),14)+")
:End
:Lbl OP:ClrHome
:sub(Str9,1+sum(lTXT,2,A-1),lTXT(A->Str0
:Menu("("+sub(Ans,1,14)+")","(LIRE)",LR,"(EDITER)",ED,"(RENOMMER)",RM,"(RETOUR)",LT
:Lbl ED
:sub(Ans,15,length(Ans)-14
:For(@,-1,0
: If @:Goto EC
:End:Goto OP
:Lbl S1
:If 3=dim(ᴸTXT:Goto ST
:If A=dim(lTXT:Then
: sub(Str9,1,sum(lTXT,2,A-1->Str9
:Else
: sum(lTXT,2,A
: sub(Str9,1,Ans-lTXT(A))+sub(Str9,1+Ans,length(Str9)-Ans->Str9
: For(@,A+1,dim(lTXT
: lTXT(@->lTXT(@-1
: End:End
:dim(lTXT)-1->dim(lTXT
:End
:Lbl ST
:" ->Str9
:{0,1->TXT
:Goto MN
:Lbl RM
:Disp "(ANCIEN NOM... )",":"+sub(Ans,1,14),"","(NOUVEAU NOM...)
:Input ":",Str0
:14+sum(lTXT,2,A-1
:sub(Str9,1,Ans-14)+sub(Str0+" ",1,14)+sub(Str9,1+Ans,length(Str9)-Ans->Str9
:Goto OP
:Lbl LR
:sub(Ans,15,length(Ans)-14->Str0
:Ans->Str1
:min(128,length(Ans->C:1->B
:Repeat @=21
: getKey->@
: If @=31:Then
: ClrHome
: Disp "(CHERCHER... )
: Input ":",Str1
: End
: If @>70 and @<103 and .1<fPart(@/10) and .5>fPart(@/10:Then
: "("+sub("0123456789",1+@-65-13iPart(@/10-7)-(@=102),1)+")->Str1
: 31->@:End
: If @=31 or @=105:Goto RC
: 16
: B+Ans(@=34)-Ans(@=25)+8Ans(@=26)-8Ans(@=24->B
: If B<1 or @=11:1->B
: 1-C+Length(Str0
: If B>Ans or @=15:Ans->B
: Output(1,1,sub(Str0,B,C
:End
:Goto OP
:Lbl RC
:inString(Str0,Str1,1+(B+15)(@=105
:If Ans:1+16iPart((Ans-1)/16->B:End
Je vous met la liste pour "comment utiliser TXT":
- Lorsque vous créez un nouveau texte, choisissez comme titre "ANNUL" pour annuler la création du nouveau texte.
- Dans le menu OUVRIR, la touche [2ND] permet de revenir au menu principal, les flèches gauche et droite servent à changer de texte. La touche [supp] supprime le texte actuellement à l'écran et la touche [annul] supprime tous les textes.
La touche [entrer] permet de sélectionner un texte pour avoir accès au options LIRE, EDITER, RENOMMER et RETOUR.
Pour échanger un texte, le receveur doit aller dans RECEVOIR du menu principal, et l'envoyeur doit sélectionner le texte à envoyer à partir du menu OUVRIR (comme vu plus haut) et attendre.
- Lors de l'édition d'un texte, faites [Rappel] + [Rep] puis validez pour rappeler le texte à éditer dans le champs d'écriture.
- Lors de la lecture d'un texte: La touche [2ND] permet de revenir aux options sur le texte, les flèches bas et haut servent à avancer et à reculer d'une ligne et les flèches gauche et droite à avancer et reculer d'une page. La touche [f( x )] vous ramène au début du texte et la touche [graph] ramène à la fin du texte.
La touche [alpha] sert à rechercher un mot dans le texte, celle-ci vous envoi au premier mot correspondant trouvé, appuyez ensuite sur la touche [entrer] pour actualiser la recherche et passer au mot correspondant suivant.
Dernier point, si vous écrivez un chiffre (compris entre 0 et 9) entre parenthèses, par exemple "(4)", et que, pendant la lecture, vous appuyez sur la touche '4' du pavé numérique, vous arrivez directement à la ligne sur laquelle se trouve "(4)", c'est une sorte de label.
TXT crée un liste "L TXT" et utilise les chaînes de caractère 0, 1 et 9, le numéro 9 étant celle qui contient les textes, les deux autres sont provisoires. Lorsque vous faite "DESINSTALLER" dans menu principal, la liste "L TXT" et la chaîne 9 sont effacées si il n'y a aucun texte. Dans tous les cas les deux chaînes provisoires sont effacées.
Pour finir (enfin ), sachez que vous pouvez créer au maximum 998 textes, mais de toute façon la mémoire sera saturée avant, chaque texte prend 23 octets + 16 octets par ligne de texte.
Autorisation : Membre
Nb de messages : 2164
Inscrit le : Sam 23 Jan 2010, 20:09
Posté le : Dim 23 Déc 2012, 14:49
Salut Maxence, bienvenue sur Tout82
Par contre si tu pouvais remplacer tous les caractères incompréhensibles dans ton code par des symboles plus simples tels que "->" ou "=/=" ce serait sympa merci.
Autorisation : Membre
Nb de messages : 8
Inscrit le : Sam 22 Déc 2012, 12:32
Posté le : Dim 23 Déc 2012, 16:36
Voila j'ai édité mon premier post, il y a maintenant le lien de la toute dernière version, elle prend 2 octets de moins ^^ (mais je suis maniaque c'est pour ça)
Et j'ai modifier le texte, maintenant il est compréhensible, mais si vous avez malgré tout des problèmes pour le lire, n'hésitez pas à me demander (par exemple pour le nombre d'espaces dans certaines lignes etc...)
Je n'ai pas vraiment eu l'occasion de le faire tester, donc c'est avec plaisir que je recevrais vos critiques si vous en avez
Autorisation : Membre
Nb de messages : 2164
Inscrit le : Sam 23 Jan 2010, 20:09
Posté le : Dim 23 Déc 2012, 23:23
Si c'est celui du TI-Concours, je me permets de rajouter la page officielle et le gif
maxence Invité
Posté le : Lun 24 Déc 2012, 0:01
Globalement c'est le même programme, mais il y a quand même des différences avec celui du ti-concours, notament au niveau de l'optimisation (entre 1000 et 2000 octets de moins je dirais), et des fonctions comme le mot de passe qui n'est plus présent car je pense que ce n'est pas très utile
Mais ce n'est pas grâve merci à toi
lol Invité
Posté le : Lun 24 Déc 2012, 0:42
salut, je n'ai pas très bien compris ton programme, que fait-il concrètement ?
Autorisation : Membre
Nb de messages : 8
Inscrit le : Sam 22 Déc 2012, 12:32
Posté le : Lun 24 Déc 2012, 11:49
Oui, en gros c'est un programme de traitement de texte, c'est plus pratique que de mettre ses textes dans des programmes, déjà au niveau visuel ça rend mieux, il n'y a pas la marque des sauts de ligne à chaque fois, mais c'est surtout les foncions qui y sont ajoutés comme la recherche, les "labels", la possibilité de renommer ses textes facilement etc... qui sont intéressantes.
Si tu veux savoir les fonctionnalités de TXT, lis le texte en bas de mon premier post qui explique comment s'en servir
Je vais quand même faire une liste ici, TXT permet de:
- Créer des textes (jusque la rien de spécial )
- Les supprimer facilement, les lires, les éditer et renommer
- D'échanger ses textes avec d'autre possesseurs de TXT via RECEVOIR (voir premier post pour plus de détails)
- Permet pendant la lecture de naviguer assez facilement en avançant ligne par ligne ou page par page par exemple, de faire des recherche de mots et d'accéder rapidement à tes chapitres grâce aux "labels" (voir premier post pour les foncions de lecture)
- Pour finir il gère la mémoire à notre place (d'une certaine manière), en supprimant la liste lTXT et les textes quand on quitte le programme et que le répertoire est vide.
Voilà, je pense que j'ai répondu à ta question "lol", s'il y a quelque chose que tu ne comprend toujours pas je suis toujours la
Autorisation : Membre
Nb de messages : 8
Inscrit le : Sam 22 Déc 2012, 12:32
Posté le : Mer 23 Jan 2013, 18:36
Je m'excuse pour le double post et aussi pour le déterrage.
J'ai remarqué qu'il y avait eu quelques téléchargements, et peut-être que certains l'on recopier également. J'aimerais savoir, pour ceux qui l'ont utilisé, ce qu'il en on pensé, ce qui est bien et ce qu'il faut changé etc...
Voila, encore désolé pour les mêmes raisons qu'au début du post :/
Autorisation : Membre
Nb de messages : 3767
Inscrit le : Lun 19 Oct 2009, 21:25
Posté le : Mer 23 Jan 2013, 20:05
Je trouve bien dommage d'avoir enlevé l'indication de position sur total et la taille dans le menu de choix.
Le rappel des actions était efficace pour une prise en main immédiate, et le serait même maintenant que les menus sont différents.
Le raccourcis de suppression totale est sauvage sans explication.
Le 2nd+recall+Ans est toujours aussi pertinent qu'avant.
Ne pas avoir à la fois Recevoir et Envoi est pratique.
Le mot de passe n'était pas utile en effet.
Pourquoi l'exemple de repere du gif utilisant "<1>" ne correspond pas au post principal qui utilise "(1)" ? Mais ça se modifie à volonté alors c'est pas grâve.
Avoir enlevé l'effet de montée/descente du texte n'est pas un mal, voire un bien à mon goût.
Même dans la version 1, j'aurais probablement voté pour toi si je n'avais pas été concurrent.
Ton programme me plait beaucoup.
---------------------- ti82statfr: 2008, inscrit: 2009, ti84pocketfr: noël2011, ti30xbmultiview: iut 2012-2014
Perfectionniste, manque tact. Pas le temps de tout publier depuis 2011. Répond toujours aux questions. (rédigé juin 2014)
Autorisation : Membre
Nb de messages : 8
Inscrit le : Sam 22 Déc 2012, 12:32
Posté le : Jeu 24 Jan 2013, 20:04
Pour ce qui est de du raccourcis de suppression il suffit de prendre la main je pense.
Pour le repère du texte sur le total et la taille, j'ai longtemps hésité à le supprimer, je vais peut-être réfléchir à ce niveau là alors.
Pour ce qui est des "<1>" et "(1)", c'est un changement de la nouvelle version, je l'ai changé parce que je me suis dit qu'il était plus facile d'accéder aux parenthèses qu'aux chevrons, et de plus c'est plus en accord avec le thème de TXT qui est bourré de parenthèses
Pour l'effet de montée/descente, c'est que la version pour le concours était "stylisée", en principe je le mettais pas dans les versions antérieurs (il y en a eu au moins un 10aine), je voulais que cette version soit la plus optimisée possible, c'est pour ça que je l'ai enlevé (c'est également pour cela que j'ai enlevé les repères du numéro du texte sur le total et la taille)
), sachez que vous pouvez créer au maximum 998 textes, mais de toute façon la mémoire sera saturée avant, chaque texte prend 23 octets + 16 octets par ligne de texte.
